/**
 * midpoints01
 *
 * Matthew Conroy (www.madandmoonly.com)
 *
 **/
  
PImage canvas1;
int numPoints=1000;
float xx [] = new float [numPoints];
float yy [] = new float [numPoints];
int color0=0;
float borderFactor=0.05;
int its=10;

void setup (){
  size(600, 600);
  canvas1 = createImage(600,600,RGB);
  // noLoop();
  for (int i=0; i<numPoints; ++i) {
    xx[i]=borderFactor*canvas1.width+(1-2*borderFactor)*random(canvas1.width);
    yy[i]=borderFactor*canvas1.width+(1-2*borderFactor)*random(canvas1.height);
  }
  
}

void draw(){
  ++its;

  float maxJ=1;
  background(0);
  strokeWeight(1);
  stroke(255,0,0);
  //color0=int(random(256));
  
  //draw the polygon
  for (int i=1; i<numPoints; i++) {
      line(xx[i],yy[i],xx[i-1],yy[i-1]);
  }
  line(xx[numPoints-1],yy[numPoints-1],xx[0],yy[0]);
  
  
  //iterate and rescale
  if (its<10) {
    maxJ=1;
  }
  else {
    maxJ=exp(0.9*log(its));  
  }
  for (int j=0; j<maxJ; ++j ) { // do several iterations per draw - this makes it much faster, and more fun to watch
  float maxX=0;
  float maxY=0;
  float minX=canvas1.width;
  float minY=canvas1.height;
  
  float xx0=xx[0];
  float yy0=yy[0];
  for (int i=0; i<numPoints-1; i++) {
       xx[i]=0.5*(xx[i]+xx[i+1]);
       yy[i]=0.5*(yy[i]+yy[i+1]);
       if (xx[i]<minX) { minX=xx[i]; }
       if (xx[i]>maxX) { maxX=xx[i]; }
       if (yy[i]<minY) { minY=yy[i]; }
       if (yy[i]>maxY) { maxY=yy[i]; }
  }
  xx[numPoints-1]=0.5*(xx[numPoints-1]+xx0);
  yy[numPoints-1]=0.5*(yy[numPoints-1]+yy0);
  if (xx[numPoints-1]<minX) { minX=xx[numPoints-1]; }
  if (xx[numPoints-1]>maxX) { maxX=xx[numPoints-1]; }
  if (yy[numPoints-1]<minY) { minY=yy[numPoints-1]; }
  if (yy[numPoints-1]>maxY) { maxY=yy[numPoints-1]; }
  //rescale
  for (int i=0; i<numPoints; i++) {
    //xx[i]=xx[i]*(1.0*max(maxX,maxY))/(1.0*canvas1.width);
    //yy[i]=yy[i]*(1.0*max(maxX,maxY))/(1.0*canvas1.width);
    xx[i]=borderFactor*canvas1.width+(1-2*borderFactor)*canvas1.width*((xx[i]-minX)/(maxX-minX));
    yy[i]=borderFactor*canvas1.height+(1-2*borderFactor)*canvas1.height*((yy[i]-minY)/(maxY-minY));
  }
  
  }  //end j loop
}

void mousePressed() 
{
  redraw();
}